Let’s Play! Death Valley

Let’s Play! Death Valley

Back in the 1980s there was a set of books published by Usborne which explained about how “micros” (what we used to call home computers back then) worked, things you could do with them, and how they were going to change the world forever. They also had a few books in the range with simple type-in games and programs, written in the most cross-compatible BASIC interpretation they could manage with loads of alterations and corrections for specific platforms.

Due to the differences between the ZX81, Spectrum, TRS-80, Apple and BBC Micro, it was apparent that text-based “games” were going to work best as graphics were implemented and programmed vastly differently on each micro, although they did include complete and separate computer specific listings for one “graphical” game in each book.

As a child, I borrowed this series of books from the local library frequently and must have typed every program in multiple times. Eventually I bought the books myself, including a title called “The Beginner’s Computer Handbook”, which was actually a compilation of three titles – “Understanding the Micro”, “Computer Programming” and (the best one) “Computer Spacegames”.

Death Valley is one of those Computer Spacegames. It’s text-based, but uses text as primitive graphics. You pilot your spaceship down a randomly wriggling canyon, although it could just as easily be a skier on a mountain or a car on a road. I’ve typed it all in for you to play. Here’s the code, if you’re interested:

10 PRINT "DEATH VALLEY"
20 LET S=0
30 LET M=200
40 PRINT "WIDTH?"
50 INPUT W
60 LET W=INT (W/2)
70 LET L=10
80 LET Y=W
90 LET R=W
100 LET D=INT (RND*3-1)
110 IF L+D<0 OR L+D>20 THEN GO TO 100
120 LET L=L+D
130 LET Y=Y-D
140 LET R=R+D
150 LET N=L
160 GO SUB 1000
170 PRINT "I";
180 LET N=Y
190 GO SUB 1000
200 PRINT "*";
210 LET N=R
220 GO SUB 1000
230 PRINT "I"
240 LET I$=INKEY$
250 IF I$<>"Q" AND I$<>"q" THEN GO TO 280
260 LET Y=Y-1
270 LET R=R+1
280 IF I$<>"P" AND I$<>"p" THEN GO TO 310
290 LET Y=Y+1
300 LET R=R-1
310 IF Y<1 OR R<1 THEN GO TO 370
320 LET S=S+1
330 IF S<M THEN GO TO 100
340 PRINT "WELL DONE-YOU MADE IT"
350 PRINT "THROUGH DEATH VALLEY"
360 STOP 
370 PRINT "YOU CRASHED INTO THE WALL"
380 PRINT "AND DISINTEGRATED"
390 STOP 
1000 IF N=0 THEN RETURN 
1010 FOR I=1 TO N
1020 PRINT " ";
1030 NEXT I
1040 RETURN

So much game in so few lines of text. Amazing.

Actually, I’ve slightly modified it from the listing in the book, as lines 250 and 280 were only looking for uppercase Q and P to “steer”, so now they check for lowercase as well.

[includeme src=”http://torinak.com/qaop#l=https://lofi-gaming.org.uk/tools/speccygames/DeathValley.tap” frameborder=”0″ width=”440″ height=”330″]

To start, press R (for RUN) then Return. The instructions, from the original Computer Spacegames book, are:

Death Valley Instructions

The emulator used is Qaop/JS – a rather spiffy HTML5 Spectrum emulator.

Leave a Reply

This site uses Akismet to reduce spam. Learn how your comment data is processed.